Συστήματα διαφορικών εξισώσεων

Στήσιμο συστήματος

Clear["Global`*"]
system1 = x'[t] == -(1/4) x[t] + 2 y[t]
system2 = y'[t] == -8 x[t] - 1/4 y[t]

(x')[t]=-\frac{1}{4} x(t)+2 y(t)

(y')[t]=-8 x(t)-(\frac{1}{4}) y(t)

Γενική λύση

DSolve[{system1, system2}, {x[t], y[t]}, t]

{{x(t)\to (E^{-t/4}) C_{1} \cos(4 t)+(\frac{1}{2}) (E^{-t/4}) C_{2} \sin(4 t),y(t)\to (E^{-t/4}) C_{2} \cos(4 t)-2 (E^{-t/4}) C_{1} \sin(4 t)}}

Με αρχικές συνθήκες

initX = x[0] == 1
initY = y[0] == 10
sol = DSolve[{system1, system2, initX, initY}, {x[t], y[t]}, t]

\(x(0)=1\)

\[y(0)=10\]

{{x(t)\to (E^{-t/4}) (\cos(4 t)+5 \sin(4 t)),y(t)\to 2 (E^{-t/4}) (5 \cos(4 t)-\sin(4 t))}}

Ορισμός συναρτήσεων-λύσεων.

xSol[t_] := Evaluate[x[t] /. sol[[1]][[1]]]
ySol[t_] := Evaluate[y[t] /. sol[[1]][[2]]]

Σχεδίαση λύσεων

Plot[{xSol[t], ySol[t]}, {t, 0, 20}]

ParametricPlot[{xSol[t], ySol[t]}, {t, 0, 20}]
ParametricPlot3D[{xSol[t], ySol[t], t}, {t, 0, 20}]

Γραφική επίλυση με StreamPlot. Ας δούμε τι θα χρησιμοποιήσουμε!

system1[[2]]
system2[[2]]
initX[[2]]
initY[[2]]

-\frac{1}{4} x(t)+2 y(t)

-8 x(t)-(\frac{1}{4}) y(t)

1

10

StreamPlot[{-(x/4) + 2 y, -8 x - y/4}, {x, -5, 5}, {y, -15, 15}, 
 StreamColorFunction -> None, 
 StreamPoints -> {{{{initX[[2]], initY[[2]]}, Red}, {{-1, 4}, Green}, 
    Automatic}}]